cppcheck

Der Compiler ist nicht genug!

Nicht erst seit der Rust Bedrohung braucht C++ Code jedes Codereview, das es kriegen kann.

cppcheck war und ist “das” Standard-Tool, dass hier den Anfang macht.

Statische Code-Analyse hilft Fehler zu erkennen, die Entwicklung und Compiler nicht als solche ansehen.
Es macht also Sinn den eigenen Code durch möglichst viele Tests zu jagen und Fehlermeldung und Hinweise einzusammeln.

cppcheck erkennt viele Formfehler wie uninitialisierte Variablen, oder “seltsam” aussehende Blockverzweigungen und noch vieles mehr.
Ich habe das Tool daher als CMake-Custom-Target eingebaut, womit ich es während der Entwicklung immer wieder direkt per VSCode-Klick ausführen kann um Verbesserunen oder Verschlechterungen in neuem Code zu erkennen.

cppcheck als CMake Target

Ein Code sagt mehr als tausend Worte:

 
 if(CMAKE_HOST_WIN32)
   find_program(CPPCHECK_APP
     NAMES "cppcheck"
     PATHS "C:\\Program Files\\Cppcheck" "C:\\Program Files (x86)\\Cppcheck" "C:\\Cppcheck")
 else()
   find_program(CPPCHECK_APP cppcheck)
 endif()
 
if(CPPCHECK_APP)

  option(CPPCHECK_CMAKE_TARGETS "Adds a CPPCHECK targets to analyze code quality" ON)
  set(CPPCHECK_SOURCE_DIR "${CMAKE_SOURCE_DIR}" CACHE FILEPATH "CPPCHECK source scan directory")
  set(CPPCHECK_RESULTS_XML_FILE "${CMAKE_BINARY_DIR}/cppcheck_results.xml" CACHE FILEPATH "CPPCHECK results output file")
  set(CPPCHECK_RESULTS_HTML_DIR "${CMAKE_BINARY_DIR}/cppcheck_report"  CACHE PATH "CPPCHECK HTML report output directory")

  if(CPPCHECK_CMAKE_TARGETS)

    set(CPPCHECK_CMD "${CPPCHECK_APP}" 
      --enable=all --language=c++ --std=c++11
      --suppress=cstyleCast
      --xml --xml-version=2 -j 8 . 2> "${CPPCHECK_RESULTS_XML_FILE}"
    )

    ## add CPPCHECK process execution target
    add_custom_target(cppcheck_execute
      COMMAND ${CPPCHECK_CMD}
      WORKING_DIRECTORY "${CPPCHECK_SOURCE_DIR}"
      COMMENT "Running cppcheck..."
    )

    file(MAKE_DIRECTORY "${CPPCHECK_RESULTS_HTML_DIR}")

    set(CPPCHECK_REPORT_CMD cppcheck-htmlreport 
      "--title=${PROJECT_NAME}" 
      --source-dir=. 
      "--file=${CPPCHECK_RESULTS_XML_FILE}" 
      "--report-dir=${CPPCHECK_RESULTS_HTML_DIR}"
    )

    ## add CPPCHECK HTML report generation target
    add_custom_target(cppcheck_generate_report
      COMMAND ${CPPCHECK_REPORT_CMD}
      WORKING_DIRECTORY "${CPPCHECK_SOURCE_DIR}"
      COMMENT "Generating cppcheck html report"
    )
  endif(CPPCHECK_CMAKE_TARGETS)
endif()

Hier werden zwei zusätzlich Targets angelegt:

• cppcheck_execute führt cppcheck aus und generatiert die XML-Datei mit gefundenen Problemen.
• cppcheck_generate_report lässt über das Tool cppcheck-htmlreport aus der XML Datei eine HTML Seite generieren.

Natürlich müssen beide Tools im Vorfeld im System installiert sein, damit sie auch gefunden und ausgeführt werden können.

In Visual Studio Code erscheinen die beiden Targets im CMake Fenster im Project Outline und können jeweils per Klick gestartet werden.

Fazit

Natürlich könnte man die beiden Tool-Ausführungen in ein Custom-Target zusammenfassen, um nur noch einen Klick zu brauchen.
Der Hintergrund für Trennung war Windows, denn die Standard-Installation von cppcheck führt dort html-report Tool nicht mit. Linux Paketmanager installieren aber immer beide Tools.

So konnte ich dann entscheiden, ob ich nur den ersten oder beide Schritte ausführen wollte.

Die Ergebnisse auf der HTML Seite haben mir schon oft Grund für kleine Änderungen und Verbesserungen gegeben.
Folglich sollte eine cppcheck Auswertung in keinem Projekt mehr fehlen.